Home  付録

シリアル値

日付

日付と時刻は，シリアル値という数値によって管理されています。
1900年1月1日のシリアル値は 1，1900年1月2日のシリアル値は 2，… のように決められます。
オプション設定により，起点日を1900年から1904年に変更することもできます。

日付シリアル値
（1900）		シリアル値
（1904）
1900年1月1日1–
1900年1月2日2–
1900年1月3日3–
⋮⋮⋮
1904年1月1日14620
1904年1月2日14631
1904年1月3日14612
⋮⋮⋮

1900年2月29日

1900年は平年ですが，1900年2月29日という存在しない日付にシリアル値が割り当てられています。

日付シリアル値
（1900）		シリアル値
（VBA）
1900年1月1日12
1900年1月2日23
1900年1月3日34
⋮⋮⋮
1900年2月28日5960
1900年2月29日60（61）
1900年3月1日6161
⋮⋮⋮

この問題について，Microsoft サポートページ http://support.microsoft.com/kb/106339/ja には，次のように説明されています（現在は閲覧不可）。

Excel の日付システムは、他の表計算ソフトとの互換性を完全に満たすように定義されています。しかしながら、この日付システムにおいて、1900 年は事実に反して閏 (うるう) 年として解釈されています。

オプション設定で「1904年から計算する」に変更すると，この問題を回避できます。
なお，VBAでは不具合が修正されています。

時刻

シリアル値は1日ごとに1ずつ変化します。シリアル値の整数部分で日付を，シリアル値の小数部分で時刻を表現できるようになっています。

たとえば，1904年1月1日のシリアル値は1462なので， 1904年1月1日午前0時に対応するシリアル値は1462.00000，1904年1月1日正午に対応するシリアル値は1462.50000，1904年1月1日午後11時59分59秒に対応するシリアル値は約1462.99999になります。

日付時刻シリアル値
（1900）
1904年1月1日00:00:001462.00000
1904年1月1日02:24:001462.10000
1904年1月1日12:00:001462.50000
1904年1月1日18:00:001462.75000
1904年1月1日23:59:591462.99999

2014.9.29 作成 / 2020.12.31 更新

空白の個数

COUNT，COUNTA，COUNTBLANK の戻り値

COUNT は数値が含まれるセルの個数，COUNTA は空でないセルの個数，COUNTBLANK は空のセルの個数を返します。

COUNT(値1, [値2], …)
COUNTA(値1, [値2], …)
COUNTBLANK(参照)

COUNT と COUNTA は，引数に 値1, 値2, … を指定できますが，COUNTBLANK はできません。
各関数とも，セル範囲の参照を指定できます。

戻り値の比較：

各関数にセル範囲の参照を指定して，戻り値を比較します。
個数をカウントするものは 1，個数をカウントしないものは 0 としています。

COUNTCOUNTACOUNTBLANK
数値110
論理値010
空でない文字列010
空文字列011
エラー値010
空セル001

ほとんどの値は，COUNTA と COUNTBLANK のどちらか一方でカウントされますが，例外があります。

空文字列，空白文字，空セルに対して，COUNTA と COUNTBLANK の戻り値がまちまちです。

関連

引数と戻り値

2021.1.13 作成 / 2021.1.14 更新

累乗根の求め方

平方根

平方根を求めるために SQRT，POWER 関数，または ^ 演算子が使えます。

=SQRT(数値)
=POWER(数値, 1/2)
=数値^(1/2)
EXCEL の数式結果備考
=SQRT(25)5\(\sqrt{25}=5\)
=SQRT(0)0\(\sqrt{0}=0\)
=SQRT(−25)#NUM!

立方根

立方根を求めるために POWER 関数または ^ 演算子が使えます。

=POWER(数値, 1/3)
=数値^(1/3)
EXCEL の数式結果備考
=POWER(8,1/3)2\(\sqrt[3]{8}=2\)
=POWER(0,1/3)0\(\sqrt[3]{0}=0\)
=POWER(−8,1/3)−2\(\sqrt[3]{-8}=-2\)

一般の累乗根

平方根，立方根，4乗根，5乗根等のことを，あわせて累乗根といいます。
累乗根を求めるために POWER 関数または ^ 演算子が使えます。 指数 には正の整数を指定します。

=POWER(数値, 1/指数)
=数値^(1/指数)

平方根，4乗根，6乗根など：

EXCEL の数式結果備考
=POWER(81,1/4)3\(\sqrt[4]{81}=3\)
=POWER(0,1/4)0\(\sqrt[4]{0}=0\)
=POWER(−81,1/4)#NUM!

立法根，5乗根，7乗根など：

EXCEL の数式結果備考
=POWER(243,1/5)3\(\sqrt[5]{243}=3\)
=POWER(0,1/5)0\(\sqrt[5]{0}=0\)
=POWER(−243,1/5)−3\(\sqrt[5]{-243}=-3\)

2021.1.7 作成 / 2021.1.7 更新

POWER

底が正の場合のべき乗

POWER 関数と ^ 演算子は同じ結果を返します。

=POWER(底, 指数)
=底^指数

底が正のとき，POWER のかわりに，EXP と LN を使って置き換えることもできます。

=EXP(LN(底)*指数)
\[ \mathrm{POWER}(x,y)=x^y=e^{y\ln x}=\mathrm{EXP}(\mathrm{LN}(x)*y) \]
EXCEL の数式結果備考
=POWER(2,2)422=4
=POWER(2,1)221=2
=POWER(2,0)120=1
=POWER(2,−1)0.52−1=1/21=0.5
=POWER(2,−2)0.252−2=1/22=0.25

底が０の場合のべき乗

POWER 関数と ^ 演算子は同じ結果を返します。

=POWER(0, 指数)
=0^指数
EXCEL の数式結果備考
=POWER(0,2)002=0
=POWER(0,1)001=0
=POWER(0,0)#NUM!
=POWER(0,−1)#DIV/0!0−1=1/01=1/0
=POWER(0,−2)#DIV/0!0−2=1/02=1/0

底が負，指数が整数の場合のべき乗

POWER 関数と ^ 演算子は同じ結果を返します。

=POWER(底, 指数)
=底^指数
EXCEL の数式結果備考
=POWER(−2,2)4(−2)2=4
=POWER(−2,1)−2(−2)1=−2
=POWER(−2,0)1(−2)0=1
=POWER(−2,−1)−0.5(−2)−1=1/(−2)1=−0.5
=POWER(−2,−2)0.25(−2)−2=1/(−2)2=0.25

底が負，指数が整数でない場合のべき乗

POWER 関数と ^ 演算子は同じ結果を返します。

=POWER(底, 指数)
=底^指数

例：

負数の3乗根

EXCEL の数式結果EXCEL の数式結果備考
=POWER(8,2)64=POWER(−8,2)642乗
=POWER(8,5/3)32=POWER(−8,5/3)#NUM!
=POWER(8,4/3)16=POWER(−8,4/3)#NUM!
=POWER(8,1)8=POWER(−8,1)−81乗
=POWER(8,2/3)4=POWER(−8,2/3)#NUM!
=POWER(8,1/3)2=POWER(−8,1/3)−2
=POWER(8,0)1=POWER(−8,0)10乗
=POWER(8,−1/3)0.5=POWER(−8,−1/3)−0.5
=POWER(8,−2/3)0.25=POWER(−8,−2/3)#NUM!
=POWER(8,−1)0.125=POWER(−8,−1)−0.125−1乗

POWER(−8,1/3) は −2 を返します。 \[ \sqrt[3]{-8}=-2 \]
POWER(−8,2/3) は #NUM! を返します。4 にはなりません。 \[ \sqrt[3]{(-8)^2}=\sqrt[3]{64}=4,\qquad (\sqrt[3]{-8})^2=(-2)^2=4 \]

負数の6乗根

EXCEL の数式結果EXCEL の数式結果備考
=POWER(64,1)64=POWER(−64,1)−641乗
=POWER(64,5/6)32=POWER(−64,5/6)#NUM!
=POWER(64,2/3)16=POWER(−64,2/3)#NUM!
=POWER(64,1/2)8=POWER(−64,1/2)#NUM!
=POWER(64,1/3)4=POWER(−64,1/3)−4
=POWER(64,1/6)2=POWER(−64,1/6)#NUM!
=POWER(64,0)1=POWER(−64,0)10乗

指数は既約分数に置き換えられます。
POWER(−64,2/6) と POWER(−64,1/3) はともに −4 を返します。 \[ \sqrt[3]{-64}=-4 \]

2021.1.7 作成 / 2021.1.7 更新

加重平均

算術平均

標本（x）が 15，120，120 のとき，平均（算術平均）は次の式で求められます。 \[ \frac{x_1+x_2+\dots +x_n}{n}=\frac{15+120+120}{3}=85 \]

EXCEL で求める方法：

平均は AVERAGE 関数で求めます。
AVERAGE 関数に 15,120,120 を指定します。
セル範囲 A1:A3 に 15,120,120 が含まれるとき，AVERAGE 関数に A1:A3 を指定します。

EXCEL の数式結果
=AVERAGE(15,120,120)85
=AVERAGE(A1:A3)85

加重算術平均

標本（x）が 10，20，30，重み（w）が 5，4，1 のとき，5個の10，4個の20，1個の30

10，10，10，10，10，20，20，20，20，30

の平均のことを加重平均といいます。

標本 x に重み w を付けた平均（加重平均）は，xw の合計を w の合計で割った値になります。

標本（x）重み（w）x × w
1.10550
2.20480
3.30130
合計—10160
\[ \frac{w_1 x_1+w_2 x_2+\dots +w_n x_n}{w_1+w_2+\dots +w_n}=\frac{5\times 10+4\times 20+1\times 30}{5+4+1}=16 \]

EXCEL で求める方法：

加重平均は SUM 関数で求めます。AVERAGE は使いません。
配列： SUM 関数に，標本 {10,20,30} と重み {5,4,1} を指定します。
参照： SUM 関数に，標本 A1:A3 と重み B1:B3 を指定して，配列数式として入力します。
参照： SUMPRODUCT 関数を使うと，配列数式にする必要がありません。

タイプEXCEL の数式結果
配列=SUM({10,20,30}∗{5,4,1})/SUM(5,4,1)16
参照{=SUM(A1:A3∗B1:B3)/SUM(B1:B3)}16（配列数式）
参照=SUMPRODUCT(A1:A3,B1:B3)/SUM(B1:B3)16

重みは {5,4,1} から {5/10,4/10,1/10} に代えることもできます。

タイプEXCEL の数式結果
配列=SUM({10,20,30}∗{5,4,1}/SUM(5,4,1))16
参照{=SUM(A1:A3∗B1:B3/SUM(B1:B3))}16（配列数式）
参照=SUMPRODUCT(A1:A3,B1:B3/SUM(B1:B3))16

※ 配列数式を入力するには，Ctrl と Shift を押しながら，Enter キーを押します。

2021.1.13 作成 / 2021.1.15 更新

幾何平均

幾何平均

標本（x）が 15，120，120 のとき，幾何平均は次の式で求められます。 \[ \sqrt[n]{x_1\times x_2\times \dots \times x_n \vphantom{0}}=\sqrt[3]{15\times 120\times 120}=60 \]

EXCEL で求める方法：

幾何平均は GEOMEAN 関数で求めます。
GEOMEAN 関数に 15,120,120 を指定します。
セル範囲 A1:A3 に 15,120,120 が含まれるとき，GEOMEAN 関数に A1:A3 を指定します。

EXCEL の数式結果
=GEOMEAN(15,120,120)60
=GEOMEAN(A1:A3)60

幾何平均が算術平均より大きくなることはありません。

GEOMEAN ≤ AVERAGE

加重幾何平均

標本（x）が 3，6，24，重み（w）が 2，4，1 のとき，2個の3，4個の6，1個の24

3，3，6，6，6，6，24

の幾何平均のことを加重幾何平均といいます。

標本 x に重み w を付けた幾何平均（加重幾何平均）を求めるには，xw の積と w の和を求めます。
xw の積は 67，w の和は 7 なので，加重幾何平均は 67 の7乗根になります。

標本（x）重み（w）xw
1.3232
2.6464
3.241241
和・積—和=7積=67
\[ \sqrt[w_1+w_2+\dots +w_n]{x_1^{w_1}\times x_2^{w_2}\times \dots \times x_n^{w_n}}=\sqrt[2+4+1]{3^2\times 6^4\times 24^1}=6 \]

EXCEL で求める方法：

加重平均は PRODUCT 関数で求めます。GEOMEAN は使いません。
配列： PRODUCT 関数に，標本 {3,6,24} と重み {2,4,1} を指定します。
参照： PRODUCT 関数に，標本 A1:A3 と重み B1:B3 を指定して，配列数式として入力します。

タイプEXCEL の数式結果
配列=PRODUCT({3,6,24}^{2,4,1})^(1/SUM(2,4,1))6
参照{=PRODUCT(A1:A3^B1:B3)^(1/SUM(B1:B3))}6（配列数式）

重みは {2,4,1} から {2/7,4/7,1/7} に代えることもできます。

タイプEXCEL の数式結果
配列=PRODUCT({3,6,24}^({2,4,1}/SUM(2,4,1)))6
参照{=PRODUCT(A1:A3^(B1:B3/SUM(B1:B3)))}6（配列数式）

※ 配列数式を入力するには，Ctrl と Shift を押しながら，Enter キーを押します。

付録：幾何平均とLN

幾何平均は，対数変換することによって，算術平均で求めることもできます。 \[ \sqrt[n]{x_1\times x_2\times \dots \times x_n}=\exp \frac{\ln x_1+\ln x_2+\dots +\ln x_n}{n} \]

タイプEXCEL の数式結果
配列=EXP(AVERAGE(LN({15,120,120})))60
参照{=EXP(AVERAGE(LN(A1:A3)))}60（配列数式）

加重幾何平均も，対数変換できます。 \[ \sqrt[w_1+w_2+\dots +w_n]{x_1^{w_1}\times x_2^{w_2}\times \dots \times x_n^{w_n}}=\exp \frac{w_1\ln x_1+w_2\ln x_2+\dots +w_n\ln x_n}{w_1+w_2+\dots +w_n} \]

タイプEXCEL の数式結果
配列=EXP(SUM(LN({3,6,24})∗{2,4,1}/SUM(2,4,1)))6
参照{=EXP(SUM(LN(A1:A3)∗B1:B3/SUM(B1:B3)))}6（配列数式）
参照=EXP(SUMPRODUCT(LN(A1:A3),B1:B3/SUM(B1:B3)))6

2021.1.13 作成 / 2021.1.15 更新

調和平均

調和平均

標本（x）が 15，120，120 のとき，調和平均は次の式で求められます。 \[ \frac{n}{\frac{1}{x_1}+\frac{1}{x_2}+\dots +\frac{1}{x_n}}=\frac{3}{\frac{1}{15}+\frac{1}{120}+\frac{1}{120}}=36 \]

EXCEL で求める方法：

平均は HARMEAN 関数で求めます。
HARMEAN 関数に 15,120,120 を指定します。
セル範囲 A1:A3 に 15,120,120 が含まれるとき，HARMEAN 関数に A1:A3 を指定します。

EXCEL の数式結果
=HARMEAN(15,120,120)36
=HARMEAN(A1:A3)36

調和平均が幾何平均より大きくなることはありません。

HARMEAN ≤ GEOMEAN ≤ AVERAGE

加重調和平均

標本（x）が 3，6，12，重み（w）が 5，3，1 のとき，5個の3，3個の6，1個の12

3，3，3，3，3，6，6，6，12

の調和平均のことを加重調和平均といいます。

標本 x に重み w を付けた調和平均（加重調和平均）は，w の合計を w/x の合計で割った値になります。

標本（x）重み（w）w / x
1.355/3
2.633/6
3.1211/12
合計—927/12
\[ \frac{w_1+x_2+\dots +w_n}{w_1\times \frac{1}{x_1}+w_2\times \frac{1}{x_2}+\dots +w_n\times \frac{1}{x_n}}=\frac{5+3+1}{5\times \frac{1}{3}+3\times \frac{1}{6}+1\times \frac{1}{12}}=4 \]

EXCEL で求める方法：

加重平均は SUM 関数で求めます。HARMEAN は使いません。
配列： SUM 関数に，標本 {3,6,12} と重み {5,3,1} を指定します。
参照： SUM 関数に，標本 A1:A3 と重み B1:B3 を指定して，配列数式として入力します。
参照： SUMPRODUCT 関数を使うと，配列数式にする必要がありません。

タイプEXCEL の数式結果
配列=SUM(5,3,1)/SUM({5,3,1}/{3,6,12})4
参照{=SUM(B1:B3)/SUM(B1:B3/A1:A3)}4（配列数式）
参照=SUM(B1:B3)/SUMPRODUCT(1/A1:A3,B1:B3)4

重みは {5,3,1} から {5/9,3/9,1/9} に代えることもできます。

タイプEXCEL の数式結果
配列=SUM({3,6,12}^−1∗{5,3,1}/SUM(5,3,1))^−14
参照{=SUM(A1:A3^−1∗B1:B3/SUM(B1:B3))^−1}4（配列数式）
参照=SUMPRODUCT(A1:A3^−1,B1:B3/SUM(B1:B3))^−14

※ 配列数式を入力するには，Ctrl と Shift を押しながら，Enter キーを押します。

2021.1.13 作成 / 2021.1.15 更新

A1参照形式

COLUMN

COLUMN 関数にセル参照を指定すると，列番号が返されます。

COLUMN(参照)
EXCEL の数式結果
=COLUMN(C1)3
=COLUMN(INDIRECT("C1"))3
=COLUMN(INDIRECT("C"&1))3

A1 参照形式の列番号は，次の EXCEL 数式で十進の列番号に変換できます。

COLUMN(INDIRECT(文字列 &1))
EXCEL の数式A1形式結果
=COLUMN(INDIRECT("A"&1))A1
=COLUMN(INDIRECT("AA"&1))AA27
=COLUMN(INDIRECT("AAA"&1))AAA703
=COLUMN(INDIRECT("XFD"&1))XFD16384

※ EXCEL のシートは最大で 1048576 行まで，16384 列まで使用できます。

ADDRESS

ADDRESS 関数に行番号と列番号を指定すると，セル参照が返されます。 引数に 4 を指定すると，相対参照の A1 参照形式の文字列が得られます。

ADDRESS(行番号, 列番号, 4)
EXCEL の数式結果
=ADDRESS(1,3,4)C1
=SUBSTITUTE(ADDRESS(1,3,4),"1","")C

十進の列番号は，次の EXCEL 数式で A1 参照形式の列番号に変換できます。

SUBSTITUTE(ADDRESS(1, 列番号, 4),"1","")
EXCEL の数式十進結果
=SUBSTITUTE(ADDRESS(1,1,4),"1","")1A
=SUBSTITUTE(ADDRESS(1,27,4),"1","")27AA
=SUBSTITUTE(ADDRESS(1,703,4),"1","")703AAA
=SUBSTITUTE(ADDRESS(1,16384,4),"1","")16384XFD

二十六進から十進へ

A1 参照形式は，各文字に A=1，B=2，C=3，…，Z=26 を対応させた二十六進法と見なせます。 ただし 0 に対応する文字がないので，普通の二十六進法ではありません。

一般に，最下位の桁は 1 の個数を表し，下から2桁目は 26 の個数を表し，下から3桁目は 26×26 の個数を表します。
二十六進の "ABC" を十進の数値に変換するとき，最下位の "C" が 3×1 に，2桁目の "B" が 2×26 に，3桁目の "A" が 1×26×26 に対応します。

"ABC" = 1×262 + 2×26 + 3×1 = 731
EXCEL の数式A1の値結果
=IFERROR(CODE(MID(A1,LEN(A1),1))−64,0)ABC3（1桁目）
=IFERROR((CODE(MID(A1,LEN(A1)−1,1))−64)∗26,0)ABC52（2桁目）
=IFERROR((CODE(MID(A1,LEN(A1)−2,1))−64)∗676,0)ABC676（3桁目）
上の3桁の合計 →ABC731（1～3桁目）

A1 参照形式の列番号は，次の EXCEL 数式で十進の列番号に変換できます。

=IFERROR((CODE(MID(文字列,LEN(文字列)−2,1))−64)∗676,0)
+IFERROR((CODE(MID(文字列,LEN(文字列)−1,1))−64)∗26,0)
+IFERROR(CODE(MID(文字列,LEN(文字列),1))−64,0)

十進から二十六進へ

X を 26 で割ったときの商 Q と 剰余 R を次のように定義します。これは普通の除法とは異なります。

Q=INT((X−1)/26),  R=MOD(X−1,26)+1

この特殊な除法を繰り返して，十進の数値を二十六進の文字列に変換できます。
十進の数値 1357 を二十六進の文字列に変換するとき，
上の除法を使って 1357 を 26 で割ると，商は 52，剰余は 5 です。
その商 52 を 26 で割ると，商は 1，剰余は 26 です。
その商 1 を 26 で割ると，商は 0，剰余は 1 です。商が0になったら終了です。

X ÷ 26QR
1357 ÷ 26525（R=5 → 1桁目=E）
52 ÷ 26126（R=26 → 2桁目=Z）※ Q=2, R=0 ではない
1 ÷ 2601（R=1 → 3桁目=A）
EXCEL の数式A1の値結果
=IF(A1>0,CHAR(MOD(A1−1,26)+1+64),"")1357E（1桁目）
=IF(A1>26,CHAR(MOD(INT((A1−1)/26)−1,26)+1+64),"")1357Z（2桁目）
=IF(A1>702,CHAR(INT((A1−27)/676)+64),"")1357A（3桁目）
上の3桁の連結 →1357AZE（1～3桁目）

十進の列番号は，次の EXCEL 数式で A1 参照形式の列番号に変換できます。

=IF(列番号>702,CHAR(INT((列番号−27)/676)+64),"")
&IF(列番号>26,CHAR(MOD(INT((列番号−1)/26)−1,26)+1+64),"")
&IF(列番号>0,CHAR(MOD(列番号−1,26)+1+64),"")

早見表

1A 27AA 53BA 79CA 128DX
2B28AB54BB80CB256IV
3C29AC55BC81CC512SR
4D30AD56BD82CD1024AMJ
5E31AE57BE83CE2048BZT
6F32AF58BF84CF4096FAN
7G33AG59BG85CG8192LCB
8H34AH60BH86CH16384XFD
9I35AI61BI87CI
10J36AJ62BJ88CJ
11K37AK63BK89CK
12L38AL64BL90CL
13M39AM65BM91CM
14N40AN66BN92CN
15O41AO67BO93CO
16P42AP68BP94CP
17Q43AQ69BQ95CQ
18R44AR70BR96CR
19S45AS71BS97CS
20T46AT72BT98CT
21U47AU73BU99CU
22V48AV74BV100CV
23W49AW75BW101CW
24X50AX76BX102CX
25Y51AY77BY103CY
26Z52AZ78BZ104CZ

2021.1.17 作成 / 2021.1.20 更新

ジュリアンデート

ジュリアンデートの作り方

ジュリアンデートとは，日付を1月1日からの通算の日数で表したものです。
1月1日は1日目，平年の12月31日は365日目，閏年の12月31日は366日目です。
2001年1月1日のジュリアンデートは "2001001" になります。

=TEXT(A1,"yyyy")&TEXT(A1−DATEVALUE(TEXT(A1,"yyyy")&"/1/1")+1,"000")

1月1日からの日数と12月31までの日数を併記したジュリアンデートもあります。
平年の3月1日のジュリアンデートは "60/306" になります。

=A1−DATEVALUE(TEXT(A1,"yyyy")&"/1/1")+1&"/"
&DATEVALUE(TEXT(A1,"yyyy")&"/12/31")−A1+1
日付シリアル値ジュリアンデートジュリアンデート
2001/1/13689220010011/365
2001/2/136923200103232/334
2001/3/136951200106060/306
2001/12/31372562001365365/1

2021.2.6 作成 / 2021.2.6 更新

PERMUTATIONA

0の0乗が不定であること

x > 0 のとき一般に x0 = 1 が成り立つが， x = 0 のときは成り立たず EXCEL では 00 がエラー値 #NUM! になる。

xy数式結果
00=POWER(A2,B2)#NUM!
0.50=POWER(A3,B3)1
10=POWER(A4,B4)1
1.50=POWER(A5,B5)1
20=POWER(A6,B6)1

y > 0 のとき一般に 0y = 0 が成り立つが， y = 0 のときは成り立たず EXCEL では 00 がエラー値 #NUM! になる。

xy数式結果
00=POWER(A2,B2)#NUM!
00.5=POWER(A3,B3)0
01=POWER(A4,B4)0
01.5=POWER(A5,B5)0
02=POWER(A6,B6)0

PERMUTATIONA（Excel 2013）

PERMUTATIONA(n, k)

総数 n のものから抜き取り数 k のものを取る重複順列の数が返される。 総数 n に指定できる値の範囲は n ≥ 0 で， n = 0 も指定できるようになっている。 \[ \text{PERMUTATIONA}(n, k) = n^k \] 特に総数が n = 0 の場合の重複順列の数は次の式で求められる。 \[ \text{PERMUTATIONA}(0, k) = 0^k,\qquad k=0,1,2,\dots \] k = 0 のときに 0の0乗 が現れて本来なら計算できないはずだが， PERMUTATIONA 関数の結果は 1 になっている。 \[ \text{PERMUTATIONA}(0, 0) = 0^0 = 1 \]

nk数式結果
00=PERMUTATIONA(A2,B2)1
01=PERMUTATIONA(A3,B3)0
02=PERMUTATIONA(A4,B4)0
03=PERMUTATIONA(A5,B5)0

重複順列の計算結果 PERMUTATIONA(0, 0) = 1 が正当かどうかは判断できないが，0の0乗が現れないように定義式を修正しなければならない。

k = 1, 2, 3, … の場合はそのままでよい。 \[ \text{PERMUTATIONA}(n, k) = n^k,\qquad k = 1,2,3,\dots \] k = 0 の場合は0の0乗が現れないように修正する。 \[ \text{PERMUTATIONA}(n, 0) = 1 \] ただしこのように定めることが正当かどうかは判断できない。

次のページへ

1 2 3 4 5 6 Next

2016.9.14 作成 / 2016.9.14 更新

COMBINA

階乗

正の整数 n に対して階乗を n! = n × (n−1) × (n−2) × … × 2 × 1 とし， n = 0 に対して 0! = 1 とする。 負の整数の階乗は定義されない。EXCEL では負の整数の階乗がエラー値 #NUM! になる。 \begin{align} &\text{FACT}(n) = n! = n (n-1) (n-2) \cdot\dots\cdot 2 \cdot 1,& n \ge 1 \\ &\text{FACT}(0) = 0! = 1 \end{align}

n数式結果
−1=FACT(A2)#NUM!
0=FACT(A3)1
1=FACT(A4)1
2=FACT(A5)2
3=FACT(A6)6

二項係数

二項係数は，総数 n のものから異なる抜き取り数 k のものを取る組合せの数を表す。 総数 n には n ≥ 0 の範囲の整数，抜き取り数 k には 0 ≤ k ≤ n の範囲の整数を指定する。 それ以外の n と k では定義できない。 EXCEL では範囲外の二項係数がエラー値 #NUM! になる。 \[ \text{COMBIN}(n, k) = \binom{n}{k} = \frac{n!}{k!(n-k)!} \]

nk数式結果
3−1=COMBIN(A2,B2)#NUM!
30=COMBIN(A3,B3)1
31=COMBIN(A4,B4)3
32=COMBIN(A5,B5)3
33=COMBIN(A6,B6)1
34=COMBIN(A7,B7)#NUM!

COMBINA（Excel 2013）

COMBINA(n, k)

総数 n のものから抜き取り数 k のものを取る重複組合せの数が返される。 総数 n に指定できる値の範囲は n ≥ 0 で， n = 0 も指定できるようになっている。 \[ \text{COMBINA}(n, k) = \binom{n+k-1}{n-1} = \frac{(n+k-1)!}{k!(n-1)!} \] 特に総数が n = 0 の場合の重複組合せの数は次の式で求められる。 \[ \text{COMBINA}(0, k) = \binom{0+k-1}{0-1} = \frac{(0+k-1)!}{k!(0-1)!},\qquad k=0,1,2,\dots \] 二項係数 COMBIN の抜き取り数に −1 が現れて（あるいは −1 の階乗が現れて）本来なら計算できないはずだが， k = 0 に限っては重複組合せ COMBINA 関数の結果が 1 になっている。 \[ \text{COMBINA}(0, 0) = \binom{0+0-1}{0-1} = \frac{(0+0-1)!}{0!(0-1)!} = 1 \]

nk数式結果
00=COMBINA(A2,B2)1
01=COMBINA(A3,B3)#NUM!
02=COMBINA(A4,B4)#NUM!
03=COMBINA(A5,B5)#NUM!

重複組合せの計算結果 COMBINA(0, 0) = 1 が正当であるとはいえないが，二項係数や階乗に −1 が現れないように定義式を修正しなければならない。

k = 1, 2, 3, … の場合はそのままでよい。 n = 0 のときはこの式は計算できないが EXCEL でもエラー値になる。 \[ \text{COMBINA}(n, k) = \binom{n+k-1}{n-1} = \frac{(n+k-1)!}{k!(n-1)!},\qquad k = 1,2,3,\dots \] k = 0 の場合は二項係数や階乗に −1 が現れないように修正する。 \[ \text{COMBINA}(n, 0) = 1 \] ただしこのように定めることは正当とはいえない。

2016.9.15 作成 / 2016.9.15 更新

BINOM.DIST

0の0乗が不定であること

x > 0 のとき一般に x0 = 1 が成り立つが， x = 0 のときは成り立たず EXCEL では 00 がエラー値 #NUM! になる。

xy数式結果
00=POWER(A2,B2)#NUM!
0.50=POWER(A3,B3)1
10=POWER(A4,B4)1
1.50=POWER(A5,B5)1
20=POWER(A6,B6)1

y > 0 のとき一般に 0y = 0 が成り立つが， y = 0 のときは成り立たず EXCEL では 00 がエラー値 #NUM! になる。

xy数式結果
00=POWER(A2,B2)#NUM!
00.5=POWER(A3,B3)0
01=POWER(A4,B4)0
01.5=POWER(A5,B5)0
02=POWER(A6,B6)0

BINOM.DIST（Excel 2010）

BINOM.DIST(x, n, p, 関数形式)

BINOM.DIST 関数に 関数形式 = FALSE を指定すると， 試行回数 n と成功率 p によって定められる二項分布の確率質量関数の値が返される。 成功率 p に指定できる値の範囲は 0 ≤ p ≤ 1 で， p = 0 や p = 1 も指定できるようになっている。 \[ \text{BINOM.DIST}(x, n, p, \text{FALSE}) = \binom{n}{x} p^x (1-p)^{n-x} \] 特に試行回数 n = 3 と成功率 p = 0 によって定められる二項分布の場合は， 確率質量関数の値が次の式で求められる。 \[ \text{BINOM.DIST}(x, 3, 0, \text{FALSE}) = \binom{3}{x} 0^x (1-0)^{3-x},\qquad x=0,1,2,3 \] x = 0 のときに 0の0乗 が現れて本来なら計算できないはずだが， BINOM.DIST 関数の結果は 1 になっている。 \[ \text{BINOM.DIST}(0, 3, 0, \text{FALSE}) = \binom{3}{0} 0^0 (1-0)^{3-0} = 1 \cdot 0^0 \cdot 1^3 = 1 \]

xnp数式結果
030=BINOM.DIST(A2,B2,C2,FALSE)1
130=BINOM.DIST(A3,B3,C3,FALSE)0
230=BINOM.DIST(A4,B4,C4,FALSE)0
330=BINOM.DIST(A5,B5,C5,FALSE)0

BINOM.DIST(0, 3, 0, FALSE) = 1 とは，成功率が 0 である試行を独立に 3 回反復したとき，そのうちの 0 回が成功する確率は 1 である，という意味である。 計算結果は正当といえるが，0の0乗が現れないように定義式を修正しなければならない。

1 ≤ x ≤ n−1 の場合はそのままでよい。 \[ \text{BINOM.DIST}(x, n, p, \text{FALSE}) = \binom{n}{x} p^x (1-p)^{n-x},\qquad 1 \le x \le n-1 \] x = 0 または x = n の場合は0の0乗が現れないように修正する。 \[ \text{BINOM.DIST}(0, n, p, \text{FALSE}) = (1-p)^n,\qquad \text{BINOM.DIST}(n, n, p, \text{FALSE}) = p^n \]

2016.8.31 作成 / 2016.9.14 更新

POISSON.DIST

0の0乗が不定であること

x > 0 のとき一般に x0 = 1 が成り立つが， x = 0 のときは成り立たず EXCEL では 00 がエラー値 #NUM! になる。

xy数式結果
00=POWER(A2,B2)#NUM!
0.50=POWER(A3,B3)1
10=POWER(A4,B4)1
1.50=POWER(A5,B5)1
20=POWER(A6,B6)1

y > 0 のとき一般に 0y = 0 が成り立つが， y = 0 のときは成り立たず EXCEL では 00 がエラー値 #NUM! になる。

xy数式結果
00=POWER(A2,B2)#NUM!
00.5=POWER(A3,B3)0
01=POWER(A4,B4)0
01.5=POWER(A5,B5)0
02=POWER(A6,B6)0

POISSON.DIST（Excel 2010）

POISSON.DIST(x, λ, 関数形式)

BINOM.DIST 関数に 関数形式 = FALSE を指定すると， 平均 λ によって定められるポアソン分布の確率質量関数の値が返される。 平均 λ に指定できる値の範囲は λ ≥ 0 で， λ = 0 も指定できるようになっている。 \[ \text{POISSON.DIST}(x, \lambda, \text{FALSE}) = \frac{\lambda^x e^{-\lambda}}{x!} \] 特に平均 λ = 0 によって定められるポアソン分布の場合は， 確率質量関数の値が次の式で求められる。 \[ \text{POISSON.DIST}(x, 0, \text{FALSE}) = \frac{0^x e^{-0}}{x!},\qquad x=0,1,2,\dots \] λ = 0 のときに 0の0乗 が現れて本来なら計算できないはずだが， POISSON.DIST 関数の結果は 1 になっている。 \[ \text{POISSON.DIST}(0, 0, \text{FALSE}) = \frac{0^0 e^{-0}}{0!} = \frac{0^0 \cdot 1}{1} = 1 \]

xλ数式結果
00=POISSON.DIST(A2,B2,FALSE)1
10=POISSON.DIST(A3,B3,FALSE)0
20=POISSON.DIST(A4,B4,FALSE)0
30=POISSON.DIST(A5,B5,FALSE)0

計算結果 POISSON.DIST(0, λ, FALSE) = 1 は正当といえるが，0の0乗が現れないように定義式を修正しなければならない。

x = 1, 2, 3, … の場合はそのままでよい。 \[ \text{POISSON.DIST}(x, \lambda, \text{FALSE}) = \frac{\lambda^x e^{-\lambda}}{x!},\qquad x = 1,2,3,\dots \] x = 0 の場合は0の0乗が現れないように修正する。 \[ \text{POISSON.DIST}(0, \lambda, \text{FALSE}) = e^{-\lambda} \]

2016.9.2 作成 / 2016.9.14 更新

付録

Home

付録  |  シリアル値  |  空白の個数  |  累乗根  |  POWER  |  加重平均  |  幾何平均  |  調和平均  |  A1参照形式  |  ジュリアンデート  |  PERMUTATIONA  |  COMBINA  |  BINOM.DIST  |  POISSON.DIST

Home › 付録