Home  逆分布関数  四分位数  統計ソフト  EXCEL  Appendix

1. 四分位数の種類

1. 四分位数の種類
2. QUARTILE関数
3. SMALL関数
4. PERCENTILE関数

I. 四分位数・分位点（Inclusive；Type7）

昇順に並べられたデータ x1，x2，…，xn に対して， P(X≤xi)=(i−1)/(n−1) を満たす矩形分布を仮定した場合の分位点。 QUARTILE.INC関数またはPERCENTILE.INC関数（QUARTILE関数またはPERCENTILE関数）で求められる。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 4017.52532.5
10 20 30 40 50203040
10 20 30 40 50 6022.53547.5
10 20 30 40 50 60 70254055

E. 四分位数・分位点（Exclusive；Type6）

昇順に並べられたデータ x1，x2，…，xn に対して， P(X≤xi)=i/(n+1) を満たす矩形分布を仮定した場合の分位点。 QUARTILE.EXC関数またはPERCENTILE.EXC関数で求められる。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 4012.52537.5
10 20 30 40 50153045
10 20 30 40 50 6017.53552.5
10 20 30 40 50 60 70204060

T. 四分位数・ヒンジ（Inclusive；Tukey）

昇順に並べられたデータ x1，x2，…，xn を等しい大きさの二群に分ける。ただしnが奇数の場合は境界値自身を両方の群に含める。 境界値を第2四分位数Q2とし，値が小さいほうの群の中央値を第1四分位数Q1，値が大きいほうの群の中央値を第3四分位数Q3とする。 この値を計算するためのEXCEL関数は用意されていない。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 40152535
10 20 30 40 50203040
10 20 30 40 50 60203550
10 20 30 40 50 60 70254055

※Tukey; John W. Tukey

M. 四分位数・ヒンジ（Exclusive；M&M）

文部科学省が指定した方法である。 昇順に並べられたデータ x1，x2，…，xn を等しい大きさの二群に分ける。ただしnが奇数の場合は境界値自身をどちらの群にも含めない。 境界値を第2四分位数Q2とし，値が小さいほうの群の中央値を第1四分位数Q1，値が大きいほうの群の中央値を第3四分位数Q3とする。 この値を計算するためのEXCEL関数は用意されていない。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 40152535
10 20 30 40 50153045
10 20 30 40 50 60203550
10 20 30 40 50 60 70204060

※M&M; David S. Moore & George P. McCabe

次のページへ

1 2 3 4 Next

2. QUARTILE関数

1. 四分位数の種類
2. QUARTILE関数
3. SMALL関数
4. PERCENTILE関数

I. 四分位数・分位点（Inclusive；Type7）の求め方

昇順に並べられたデータ x1，x2，…，xn に対して， P(X≤xi)=(i−1)/(n−1) を満たす矩形分布を仮定した場合の分位点。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 4017.52532.5
10 20 30 40 50203040
10 20 30 40 50 6022.53547.5
10 20 30 40 50 60 70254055

この型の四分位数（Inclusive）は，QUARTILE.INC関数またはPERCENTILE.INC関数（QUARTILE関数またはPERCENTILE関数）で求められる。 第2四分位数はMEDIAN関数で求めることもできる。

四分位数EXCELの数式
Q1=QUARTILE.INC(セル範囲, 1)
Q1=PERCENTILE.INC(セル範囲, 0.25)
Q2=QUARTILE.INC(セル範囲, 2)
Q2=PERCENTILE.INC(セル範囲, 0.5)
Q2=MEDIAN(セル範囲)
Q3=QUARTILE.INC(セル範囲, 3)
Q3=PERCENTILE.INC(セル範囲, 0.75)

※互換性関数QUARTILE，PERCENTILEに置き換えてもよい。

E. 四分位数・分位点（Exclusive；Type6）の求め方

昇順に並べられたデータ x1，x2，…，xn に対して， P(X≤xi)=i/(n+1) を満たす矩形分布を仮定した場合の分位点。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 4012.52537.5
10 20 30 40 50153045
10 20 30 40 50 6017.53552.5
10 20 30 40 50 60 70204060

この型の四分位数（Exclusive）は，QUARTILE.EXC関数またはPERCENTILE.EXC関数で求められる。 第2四分位数はMEDIAN関数で求めることもできる。

四分位数EXCELの数式
Q1=QUARTILE.EXC(セル範囲, 1)
Q1=PERCENTILE.EXC(セル範囲, 0.25)
Q2=QUARTILE.EXC(セル範囲, 2)
Q2=PERCENTILE.EXC(セル範囲, 0.5)
Q2=MEDIAN(セル範囲)
Q3=QUARTILE.EXC(セル範囲, 3)
Q3=PERCENTILE.EXC(セル範囲, 0.75)

次のページへ

1 2 3 4 Next

3. SMALL関数

1. 四分位数の種類
2. QUARTILE関数
3. SMALL関数
4. PERCENTILE関数

T. 四分位数・ヒンジ（Inclusive；Tukey）の求め方

昇順に並べられたデータ x1，x2，…，xn を等しい大きさの二群に分ける。ただしnが奇数の場合は境界値自身を両方の群に含める。 境界値を第2四分位数Q2とし，値が小さいほうの群の中央値を第1四分位数Q1，値が大きいほうの群の中央値を第3四分位数Q3とする。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 40152535
10 20 30 40 50203040
10 20 30 40 50 60203550
10 20 30 40 50 60 70254055

この型の四分位数（Tukeyの方法）は，次の公式で求められる。 \begin{gather*} Q_2 =\frac{x_{\lfloor (n+1)/2\rfloor}+x_{\lfloor (n+2)/2\rfloor}}{2}\\ Q_1 =\frac{x_{\lfloor (n+3)/4\rfloor}+x_{\lfloor (n+5)/4\rfloor}}{2},\qquad Q_3 =\frac{x_{\lfloor (3n+2)/4\rfloor}+x_{\lfloor (3n+4)/4\rfloor}}{2} \end{gather*}

SMALL関数等を利用して実現できる。

四分位数EXCELの数式
Q1=(SMALL(セル範囲, INT((COUNT(セル範囲)+3)/4))
 +SMALL(セル範囲, INT((COUNT(セル範囲)+5)/4)))/2
Q2=(SMALL(セル範囲, INT((COUNT(セル範囲)+1)/2))
 +SMALL(セル範囲, INT((COUNT(セル範囲)+2)/2)))/2
Q3=(SMALL(セル範囲, INT((COUNT(セル範囲)∗3+2)/4))
 +SMALL(セル範囲, INT((COUNT(セル範囲)∗3+4)/4)))/2

M. 四分位数・ヒンジ（Exclusive；M&M）の求め方

文部科学省が指定した方法である。 昇順に並べられたデータ x1，x2，…，xn を等しい大きさの二群に分ける。ただしnが奇数の場合は境界値自身をどちらの群にも含めない。 境界値を第2四分位数Q2とし，値が小さいほうの群の中央値を第1四分位数Q1，値が大きいほうの群の中央値を第3四分位数Q3とする。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 40152535
10 20 30 40 50153045
10 20 30 40 50 60203550
10 20 30 40 50 60 70204060

この型の四分位数（M&Mの方法）は，次の公式で求められる。 \begin{gather*} Q_2 =\frac{x_{\lfloor (n+1)/2\rfloor}+x_{\lfloor (n+2)/2\rfloor}}{2}\\ Q_1 =\frac{x_{\lfloor (n+2)/4\rfloor}+x_{\lfloor (n+4)/4\rfloor}}{2},\qquad Q_3 =\frac{x_{\lfloor (3n+3)/4\rfloor}+x_{\lfloor (3n+5)/4\rfloor}}{2} \end{gather*}

SMALL関数等を利用して実現できる。

四分位数EXCELの数式
Q1=(SMALL(セル範囲, INT((COUNT(セル範囲)+2)/4))
 +SMALL(セル範囲, INT((COUNT(セル範囲)+4)/4)))/2
Q2=(SMALL(セル範囲, INT((COUNT(セル範囲)+1)/2))
 +SMALL(セル範囲, INT((COUNT(セル範囲)+2)/2)))/2
Q3=(SMALL(セル範囲, INT((COUNT(セル範囲)∗3+3)/4))
 +SMALL(セル範囲, INT((COUNT(セル範囲)∗3+5)/4)))/2

次のページへ

1 2 3 4 Next

4. PERCENTILE関数を利用する

1. 四分位数の種類
2. QUARTILE関数
3. SMALL関数
4. PERCENTILE関数

T. 四分位数・ヒンジ（Inclusive；Tukey）の求め方

昇順に並べられたデータ x1，x2，…，xn を等しい大きさの二群に分ける。ただしnが奇数の場合は境界値自身を両方の群に含める。 境界値を第2四分位数Q2とし，値が小さいほうの群の中央値を第1四分位数Q1，値が大きいほうの群の中央値を第3四分位数Q3とする。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 40152535
10 20 30 40 50203040
10 20 30 40 50 60203550
10 20 30 40 50 60 70254055

この型の四分位数（Tukeyの方法）は，データサイズが奇数の場合はQUARTILE.INC関数の結果と同じになる。 データサイズが偶数の場合は，PERCENTILE.INC関数またはPERCENTILE.EXC関数の引数をうまく調整して実現できる。

四分位数EXCELの数式
Q1=PERCENTILE.INC(セル範囲,
 (EVEN(COUNT(セル範囲)+2)/4−1)/(COUNT(セル範囲)−1))
Q1=PERCENTILE.EXC(セル範囲,
 EVEN(COUNT(セル範囲)+2)/4/(COUNT(セル範囲)+1))
Q2=PERCENTILE.INC(セル範囲, 0.5)
Q2=PERCENTILE.EXC(セル範囲, 0.5)
Q3=PERCENTILE.INC(セル範囲,
 (EVEN(COUNT(セル範囲)∗3+1)/4−1)/(COUNT(セル範囲)−1))
Q3=PERCENTILE.EXC(セル範囲,
 EVEN(COUNT(セル範囲)∗3+1)/4/(COUNT(セル範囲)+1))

M. 四分位数・ヒンジ（Exclusive；M&M）の求め方

文部科学省が指定した方法である。 昇順に並べられたデータ x1，x2，…，xn を等しい大きさの二群に分ける。ただしnが奇数の場合は境界値自身をどちらの群にも含めない。 境界値を第2四分位数Q2とし，値が小さいほうの群の中央値を第1四分位数Q1，値が大きいほうの群の中央値を第3四分位数Q3とする。

データ第1四分位数 Q1第2四分位数 Q2第3四分位数 Q3
10 20 30 40152535
10 20 30 40 50153045
10 20 30 40 50 60203550
10 20 30 40 50 60 70204060

この型の四分位数（M&Mの方法）は，データサイズが奇数の場合はQUARTILE.EXC関数の結果と同じになる。 データサイズが偶数の場合は，PERCENTILE.INC関数またはPERCENTILE.EXC関数の引数をうまく調整して実現できる。

四分位数EXCELの数式
Q1=PERCENTILE.INC(セル範囲,
 (EVEN(COUNT(セル範囲)+1)/4−1)/(COUNT(セル範囲)−1))
Q1=PERCENTILE.EXC(セル範囲,
 EVEN(COUNT(セル範囲)+1)/4/(COUNT(セル範囲)+1))
Q2=PERCENTILE.INC(セル範囲, 0.5)
Q2=PERCENTILE.EXC(セル範囲, 0.5)
Q3=PERCENTILE.INC(セル範囲,
 (EVEN(COUNT(セル範囲)∗3+2)/4−1)/(COUNT(セル範囲)−1))
Q3=PERCENTILE.EXC(セル範囲,
 EVEN(COUNT(セル範囲)∗3+2)/4/(COUNT(セル範囲)+1))

最後のページです

1 2 3 4 Home

エクセルで四分位数を求める方法

Home  四分位数

2012.12.12 作成 / 2020.5.3 更新

Home › エクセルで四分位数を求める方法